***************************************************************************
*   Файл       : S_Refer.ch для программы                                 *
*                S_Refer.prg - работа со справочниками в GET-системе      *
*   Автор      : А. Титов                                                 *
*   Дата       : Янваpь 1993 г                                            *
*   Версия     : Clipper 5.01                                             *
***************************************************************************

#define KL_REFER K_F2         //Клавиша для вызова справочника
#define KL_ENTER K_RETURN     //Клавиша для выбора
#define KL_SEEK  K_F7         //Клавиша для поиска в справочнике
#define C_ENTER CHR(17)+'┘:'  //Строка для обозначения клавиши выбора
#define C_SEEK  'F7:'         //Строка для обозначения клавиши поиска

#xcommand @ <row>,<col> REFER <cRefer> GET <var> [<*etc*>];
=>@ <row>,<col> GET <var> <etc>;       ;
 ATAIL(GetList):reader := {|get|ReferGetReader(get,<cRefer>)}

#xcommand @ <row>,<col> REFRIGHT <cRefer> GET <var> [<*etc*>];
=>@ <row>,<col> GET <var> <etc>;       ;
 ATAIL(GetList):reader := {|get|ReferGetReader(get,<cRefer>)};   ;
 ATAIL(GetList):cargo  := .T.

#xcommand @ <row>,<col> REFRIGHTF <cRefer> GET <var> [<*etc*>];
=>@ <row>,<col> GET <var> <etc>;       ;
 ATAIL(GetList):reader := {|get|ReferGetReader(get,<cRefer>)};   ;
 ATAIL(GetList):cargo  := .F.

MEMVAR GetList

// определения для S_LIB
#define _bGetaIn(_i)  ;
        &("{|x|IF(x!=NIL,m->aIn[" +STR(_i)+ "]:=x,m->aIn[" +STR(_i)+ "])}")
#define _bGetaInij(_i,_j)  ;
  &("{|x|IF(x!=NIL,m->aIn[" +STR(_i)+","+STR(_j)+ "]:=x,m->aIn[" +STR(_i)+","+STR(_j)+"])}")
#define _Compile(cS)  ;
        &("{||" +cS+ "}")
#translate  _ReferReader(<cRefer>) => ;
            &("{|oGet|ReferGetReader(oGet,'" +<cRefer>+ "')}")

